看看我的网壳ansys命令流文件哪出了问题（ANSYS提示某节点位移超出最大值，模型无约束）

问题描述：

就是在求解时出现问题，请高手帮忙。（解决问题者追加悬赏分）

问题解答：

这个模型还是很复杂的。你的错误应该是：
/solu
*do,i,1,48
d,i,ux,uy,uz
*enddo
将d,i,ux,uy,uz 改为：D, i, UX, 0, , , , UY, UZ
D的命令是：D, NODE, Lab, VALUE，VALUE2, NEND, NINC, Lab2, Lab3, Lab4, Lab5, Lab6
你把UY、UZ的位置写错了

这是我的程序。
/prep7
et,1,link8
a1=0.0019625
a2=0.001256
a3=0.0007065
theta=7.5
fi=6.64125
r1=25
r2=24

R,1,a1
R,2,a2
R,3,a3

MP,EX,1,2.1E11
MP,PRXY,1,0.3
MP,DENS,1,7800

MP,EX,2,2.1e11
MP,PRXY,2,0.3
MP,DENS,2,7800

MP,EX,3,2.1e11
MP,PRXY,3,0.3
MP,DENS,3,7800

CSYS,2

*do,i,1,8
*do,j,1,48,1
n,48*(i-1)+j,r1,(j-1)*theta,(i-1)*fi+36.87
*enddo
*enddo !网壳外层节点

mat,1
real,1
*do,i,1,8
*do,j,1,47,1
e,48*(i-1)+j,48*(i-1)+j+1
*enddo
e,i*48,i*48-47
*enddo !外层网壳纬向杆连接

* do,i,1,7
*do,j,1,48,1
e,48*(i-1)+j,48*(i-1)+j+48
*enddo
*enddo !外层径向杆连接

n,769,25,0,90
*do,i,337,384,1
e,i,769
*enddo !外层顶点,与临近纬圈相连

Mat,2
real,2
*do,i,1,7
*do,j,1,47,1
E,48*(i-1)+j, 48*(i-1)+j+49
*enddo
E,i*48,i*48+1
*enddo !外层斜杆

*do,i,9,16
*do,j,1,48,1
n,48*(i-1)+j,r2,(j-1)*theta,(i-9)*fi+36.87
*enddo
*enddo !网壳内层节点

mat,1
real,1
*do,i,9,16
*do,j,1,47,1
e,48*(i-1)+j,48*(i-1)+j+1
*enddo
e,i*48,i*48-47
*enddo !内层网壳纬向杆连接

*do,i,9,15,1
*do,j,1,48,1
e,48*(i-1)+j,48*(i-1)+j+48
*enddo
*enddo !内层径向杆连接

n,770,24,0,90
*do,i,721,768,1
e,i,770
*enddo !内层顶点,与临近纬圈相连

Mat,2
real,2
*do,i,9,15
*do,j,1,47,1
E,48*(i-1)+j, 48*(i-1)+j+49
*enddo
E,i*48,i*48+1
*enddo !内层斜杆

mat,3
real,3
*do,I,1,8
*do,j,1,48,1
E,48*(i-1)+j, 48*(i-1)+j+384
*enddo
*enddo !内外层对应节点相连

*do,I,337,384,1
E,I,770
*enddo
E,769,770 !外层最上层节点和中心点与内层中心点相连

*do,i,337,383
E,i,i+385
*enddo
E,384,721 !内外层最上圈对应杆件交叉相连

*do,i,385,673,48
e,i,i-383
e,i,i-337
*enddo !0度 对应杆交叉相连

*do,i,397,421,12
*do,j,1,7
e,i+(j-1)*48,i+(j-1)*48-385
e,i+(j-1)*48,i+(j-1)*48-383
*enddo
*enddo !90度，180度，270度对应杆交叉相连

*do,i,391,427,12
*do,j,1,7
e,i+(j-1)*48,i+(j-1)*48-385
e,i+(j-1)*48,i+(j-1)*48-383
*enddo
*enddo !45度，135度，225度，315度 对应杆交叉相连

*do,i,433,475,6
*do,j,1,6
e,i+(j-1)*48,i+(j-1)*48-432
*enddo
*enddo !米字型位置加斜杆

nummrg,all
numcmp,all
finish

/solu
*do,i,1,48
d,i,ux,uy,uz
*enddo

*do,i,1,8
*do,j,1,48,1
f,48*(i-1)+j,fy,-1
*enddo
*enddo
f,769,fy,-1

*do,i,9,16
*do,j,1,48,1
f,48*(i-1)+j,fy,-1
*enddo
*enddo
f,770,fy,-1

acel,,9.8