问题描述：
想要自己做个bat文件作为闹钟
******
我的方案是这样的，晚上12点睡觉，电脑开着，开着迅雷(Thunder5.exe)和酷我音乐盒(KwMusic.exe)睡觉,
设定1点关闭酷我音乐盒，其他继续
6点关闭迅雷，然后清理垃圾文件(我有个bat文件，也可以不用那个bat文件)，完了之后打开C:\batch\起床铃声2.mp3文件作为闹钟
*******
ps:我有个清理垃圾文件的bat文件，不过代码里末尾我写上了echo. & pause 停止符，如果直接放进主bat批处理文件运行到中途要敲击任何键才能继续，不符合实际。就是希望能在运行“清理垃圾文件”bat文件之后，接着默认过了echo. & pause这一关或是有什么敲击口令，然后继续往下走设定闹钟
【原则是我不想删除“清理垃圾文件"那个bat文件中的那行字，那文件平时也有用的】
如果谁能帮我做到ps中的任务，另外加20分，谢谢高手指教哦，o(∩_∩)o...
另外补充下
6点闹钟响之后，在bat主批处理（命名为“闹钟.bat”把）目录下生成"起床.txt"文件，内容如下
老板快起床，啊啊啊啊啊啊啊啊啊~~~
现在是北京时间xxxx年x月x日 （就是这地方最头痛）
这个应该不难吧，o(∩_∩)o..
ps:
1楼说的方法很对，不过很多口令不是很会用，照样谢谢你
2楼很老练（好多都看不懂），跟上我的思路编程序，这点很佩服
3楼明显抄袭的，不过提供的一手资料还真有用，值得研究，照样谢谢了
问题解答：
本批处理虽然生成Sleep.Vbs临时文件，但其占系统资源极少！如果要隐藏批处理窗口请在
@echo off与
echo wscript.sleep 50000>"Sleep.Vbs"
之间加上以下代码：
if "%1"=="h" goto :2
mshta vbscript:createobject("wscript.shell").run("""%~nx0"" h",0)(window.close)&&exit
:2
闹钟.bat代码：
@echo off
echo wscript.sleep 50000>"Sleep.Vbs"
:K
if %time:~1,4%==1:00 goto R
if %time:~1,4%==6:00 goto T
start /wait Sleep.Vbs
goto K
:T
taskkill /im Thunder5.exe /f
echo 正在清除系统垃圾文件，请稍等......
del /f /s /q %systemdrive%\*.tmp
del /f /s /q %systemdrive%\*._mp
del /f /s /q %systemdrive%\*.log
del /f /s /q %systemdrive%\*.gid
del /f /s /q %systemdrive%\*.chk
del /f /s /q %systemdrive%\*.old
del /f /s /q %systemdrive%\recycled\*.*
del /f /s /q %windir%\*.bak
del /f /s /q %windir%\prefetch\*.*
rd /s /q %windir%\temp & md %windir%\temp
Rd /s /q "%userprofile%\recent"
Rd /s /q "%userprofile%\Local Settings\Temp"
del /f /q %userprofile%\cookies\*.*
del /f /q "%userprofile%\My Documents\*.rsnp"
del /f /q "%userprofile%\My Documents\*.htm"
echo 垃圾文件清除完毕......
start "" "C:\batch\起床铃声2.mp3"
for /f "tokens=1,2,3 delims=- " %%i in ('date /t') do set rq=%%i年%%j月%%k日
echo 老板快起床，啊啊啊啊啊啊啊啊啊~~~>"起床.txt"
echo 现在是北京时间%rq%>>"起床.txt"
start 起床.txt
start /wait Sleep.Vbs
goto K
:R
taskkill /im KwMusic.exe /f
start /wait Sleep.Vbs
goto K
楼主用你的批处理清除垃圾代码替换我的即可！
cd=1/*\..\..&@cls
@echo off & setlocal
set f="C:\清理垃圾文件.bat"
at 1:00 ntsd -c q -pn kwmusic.exe
set f=%f:"=\"%
set t=\"%~dp0起床.txt\"
for /f "tokens=1,2,3" %%a in ('cscript -nologo -e:jscript "%~f0"') do (
set y=%%a
set m=%%b
set d=%%c
)
at 6:00 cmd "/c ntsd -c q -pn thunder5.exe&echo.|%f%&start /wait \"\" \"C:\batch\起床铃声2.mp3\"&echo 老板快起床，啊啊啊啊啊啊啊啊啊~~~>%t%&echo 现在是北京时间%y%年%m%月%d%日>>%t%"
goto :eof
*/
dt = new Date()
WSH.Echo(dt.getYear(), dt.getMonth() + 1, dt.getDate())
这个要装千千静听来为你响闹钟
@echo off
color f4
mode con: cols=70 lines=20
@echo [闹钟程序 by：羽枫]
Title [闹钟程序 V1.0]
set tm1=%time:~0,2%
set tm2=%time:~3,2%
set da1=%date:~0,4%
set da2=%date:~5,2%
set da3=%date:~8,2%
mshta vbscript:msgbox("欢迎使用闹钟程序",64,"闹钟程序")(window.close)
cls
if not exist "C:\Program Files\TTPlayer\TTPlayer.exe" goto ttplayer
goto xp
:ttplayer
mshta vbscript:msgbox("您没有安装千千静听播放器或没有正确安装！请安装到 C:\Program Files\TTPlayer 目录下！",64,"错误")(window.close)
exit
:xp
if exist "c:\windows\system32\shutdown.exe" goto home
mshta vbscript:msgbox("您的操作系统不是Windows XP或者更高版本！",64,"兼容错误")(window.close)
goto end
:home
cls
echo ----------------------------------------------------------------------
echo.
echo 欢迎%username%, 今天是 %da1%年%da2%月%da3%号 时间为 %tm1%时%tm2%分
echo A、定义闹钟时间。
echo B、定义关机时间。
echo C、定义闹钟音量。
echo D、取消作业。
echo E、关闭提醒闹钟。
echo F、阻止系统关机。
echo Q、退出程序。
set /p pass=请输入要操作的代码（A、B、C、D、E、F、Q）:
set "pass=%pass:"=%"
if /i "%pass%"=="A" goto time
if /i "%pass%"=="B" goto off
if /i "%pass%"=="C" goto vol
if /i "%pass%"=="D" goto c
if /i "%pass%"=="Q" goto end
if /i "%pass%"=="E" goto notime
if /i "%pass%"=="F" goto nooff
cls
@echo msgbox"您输入的格式有误，请重试！">msg.vbs&msg.vbs&del msg.vbs
goto :home
:time
cls
set tm1=%time:~0,2%
set tm2=%time:~3,2%
echo 请输入要定义的时间，现在时间为 %tm1%时%tm2%分（输入格式为XX:XX）
set /p tm=请输入时间:
set "tm=%tm:"=%"
at %tm% "C:\Program Files\TTPlayer\TTPlayer.exe">nul
if %errorlevel% == 1 goto err
@echo msgbox"闹钟已设置成功！">msg.vbs&msg.vbs&del msg.vbs
goto home
:off
cls
set tm1=%time:~0,2%
set tm2=%time:~3,2%
echo 请输入要关机的时间，现在时间为 %tm1%时%tm2%分（输入为格式XX:XX）
set /p off=请输入时间:
set "off=%off:"=%"
at %off% shutdown -f -s -t 30 -c "系统将30秒后自动关机，请保存好您未保存的文件！ 羽枫温馨提示。">nul
if %errorlevel% == 1 goto err
@echo msgbox"定时关机设置成功！">msg.vbs&msg.vbs&del msg.vbs
goto home
:vol
cls
echo 设置闹钟音量。
rundll32.exe shell32.dll,Control_RunDLL mmsys.cpl,,0
@echo msgbox"音量设置成功！">msg.vbs&msg.vbs&del msg.vbs
goto home
:c
cls
at /delete /yes
echo.
echo.
echo.
echo 正在取消设定，请稍候！
set /p= ====================================================================<nul
set /p= <nul
for /l %%b in (1,1,69) do set /p=^><nul&ping -n 0 127.1>nul
@echo msgbox"取消设定成功">msg.vbs&msg.vbs&del msg.vbs
goto home
:end
exit
:err
@echo msgbox"您输入的格式有误，请重试！">msg.vbs&msg.vbs&del msg.vbs
goto home
:notime
cls
echo.
echo.
echo.
echo 正在关闭闹钟，请稍候！
set /p= ====================================================================<nul
set /p= <nul
for /l %%b in (1,1,69) do set /p=^><nul&ping -n 0 127.1>nul
taskkill /f /im ttplayer.exe>nul 2>nul
@echo msgbox"闹钟已关闭！">msg.vbs&msg.vbs&del msg.vbs
goto home
:nooff
cls
echo.
echo.
echo.
echo 正在阻止系统关闭，请稍候！
set /p= ====================================================================<nul
set /p= <nul
for /l %%b in (1,1,69) do set /p=^><nul&ping -n 0 127.1>nul
shutdown -a>nul 2>nul
@echo msgbox"已成功阻止！">msg.vbs&msg.vbs&del msg.vbs
goto home
定时可以用at命令,记得先开相关服务
假定你的ps dot bat和主bat在同个目录,那么要执行ps dot bat就为echo s|ps dot bat.
把 dot 改成.即可,这里利用了管道的技巧
上海旅游网