电脑有自带的调时关机功能吗？

问题描述：

我没发现呀？

问题解答：

Windows xp 的关机是由shutdown.exe程序来控制的,位于Windows/system32文件夹。如果想让windows 2000也实现同样的效果，可以把 shutdown.exe复制到系统目录下。

比如要电脑在22：00关机，单击“开始/运行”，输入“at 22:00 shutdown -s”，确定。

这样，到了22点电脑就会出现“系统关机”对话框，默认有30S的倒计时并提醒用户保存工作，如果想以倒计时方式关机，可以输入“shutdown.exe-s –t 3600”,表示60min后自动关机，“3600”代表60min。

设置好后，如果想取消，可以在“运行”中输入“shutdown -a”。另外输入”shutown -i”，则可以打开设置自动关机对话框，对自动关机进行设置。

的每个参数都具有特定的用途，执行哪一个都会产生相应的效果。

例如：-S 表示关闭本地计算机

-A 表示取消关机操作

-F 强行关闭应用程序

-M\\计算机名 控制远程计算机

-I 显示图形用户界面，但必须是shutdown的第一个选项

-L 注销当前用户

-R 关机并重启

-T 设置关机倒计时

-C“消息内容” 输入关机对话框中的消息内容（不能超过127个字符）

同意dxynew2001说的话，不过还有一个更方便的办法，就是写个P处理文件放在桌面上，想定时关机时双击一下再设一下时间就可以了，P处理文件会把自带的关机软件设好。如下面文字就是P处理的内容（我改过了，但不影响使用），将这些文字保存在记事本上，再把后缀名txt改成bat即可使用。

//从下一行开始复制，直至底行。
@ECHO off
TITLE 关机无忧

:start
CLS
COLOR 2b
rem 使用COLOR命令对控制台输出颜色进行更改
MODE con: COLS=28 LINES=20
rem MODE语句为设定窗体的宽和高

set tm1=%time:~0,2%
set tm2=%time:~3,2%
set tm3=%time:~6,2%
ECHO 当前时间
@echo off
for /f "tokens=1,2,3 delims=- " %%i in ('date /t') do echo %%i年%%j月%%k日
ECHO %tm1%点%tm2%分%tm3%秒
ECHO ◆◆◆◆◆◆◆◆◆◆◆◆◆◆
ECHO 关机无忧，坐以待币
ECHO ◇◇◇◇◇◇◇◇◇◇◇◇◇◇
ECHO A. 定时关闭计算机
ECHO B. 倒计时关闭计算机
ECHO C. 删除定时关机任务
ECHO D. 查看任务状态
ECHO E. 刷新当前时间
ECHO F. 重新启动计算机
ECHO G. 锁定计算机
ECHO H. 注销计算机
ECHO 0. 退出本程序

SET Choice=
SET /P Choice=选择:
rem 设定变量"Choice"为用户输入的字符
IF NOT "%Choice%"=="" SET Choice=%Choice:~0,1%
rem 如果输入大于1位,取第1位,比如输入132,则返回值为1
ECHO.
IF /I "%Choice%"=="A" GOTO SetHour
IF /I "%Choice%"=="B" GOTO outtime
IF /I "%Choice%"=="C" GOTO delAt
IF /I "%Choice%"=="D" GOTO view
IF /I "%Choice%"=="E" GOTO start
IF /I "%Choice%"=="F" GOTO restart
IF /I "%Choice%"=="G" GOTO lock
IF /I "%Choice%"=="H" GOTO logoff
IF /I "%Choice%"=="0" GOTO end
rem 为避免出现返回值为空或含空格而导致程序异常,需在变量外另加双引号
rem 注意,IF语句需要双等于号
rem 如果输入的字符不是以上数字,将返回重新输入
ECHO 选择无效，请重新输入
ECHO.
GOTO cho

:SetHour
CLS
ECHO.
SET ask=
SET /p ask=是否设定为每天执行关机命令(y/n):
IF NOT "%ask%"=="" SET ask=%ask:~0,1%
IF /I "%ask%"=="y" GOTO yes
IF /I "%ask%"=="n" GOTO no
GOTO SetHour

:yes
ECHO 请指定24小时制式时间,格式为 小时:分钟
SET shutdowntime=
SET /p shutdowntime=输入:
at %shutdowntime% /every:M,T,W,Th,F,S,Su tsshutdn 0 /delay:0 /powerdown >nul
rem 设定为每周的星期一至星期日,即为每天
IF NOT errorlevel 1 GOTO ok
rem 如果输入正确,就执行ok段的语句
ECHO %shutdowntime% 不是标准的时间格式,请重新输入
ECHO.
GOTO yes

:no
ECHO 请指定24小时制式时间,格式为 小时:分钟
SET shutdowntime=
SET /p shutdowntime=输入:
at %shutdowntime% tsshutdn 0 /delay:0 /powerdown >nul
IF NOT errorlevel 1 GOTO ok
ECHO %shutdowntime% 不是标准的时间格式,请重新输入
ECHO.
GOTO no

:ok
ECHO.
SET h=%shutdowntime:~1,1%
SET ah=%shutdowntime:~0,1%
SET am=%shutdowntime:~2,2%
SET bh=%shutdowntime:~0,2%
SET bm=%shutdowntime:~3,2%
IF "%h%"==":" (
SET HM=%ah%时%am%分
) ELSE (
SET HM=%bh%时%bm%分)
rem 如果输入h:mm则HM=h时mm分,否则HM=hh时mm分
IF /I "%ask%"=="y" ECHO 系统将于每天的%HM%关闭
IF /I "%ask%"=="n" ECHO 系统将于%HM%关闭
ECHO 设定完毕! 按任意键继续...
PAUSE >nul
GOTO start

:outtime
CLS
ECHO.
ECHO 请输入倒计时秒数
ECHO 直接回车60秒后关机
ECHO ★★★★★★★★★★★★★★
ECHO (设定后要取消,单击"确定"后按Ctrl+C键两次)
SET timed=
SET /p timed=输入:
tsshutdn %timed% /delay:0 /powerdown >nul
IF not errorlevel 1 GOTO ok
ECHO %timed% 是无效的关机时间,请重新输入
ECHO.
GOTO outtime

:delAt
cls
echo.
at /del /y
echo 定时关机任务已取消,按任意键继续...
pause >nul
GOTO start

:view
MODE con: COLS=80 LINES=8
COLOR 2f
ECHO.
at
ECHO 按任意键继续...
PAUSE >nul
GOTO start

:restart
shutdown -r -t 0

:lock
rundll32.exe user32.dll,LockWorkStation
goto start

:logoff
logoff

:end
exit

可以下载相关软件`
其实调也可以调的`只不过不会放出来给你看到.
要执行相关命令`