有没有人有可以转换动网论坛ubb代码为html代码的函数

问题描述：

如题,原来是用正则函数的,不过我不能弄出来单独调用
用ASP 写的

或者说,怎样通过正则函数将下面的代码
[upload=gif]UploadFile/2007-9/20079119514934253.gif[/upload][B]粗体[/B][I]斜体[/I][U]下划线[/U][center]居中[/center] [EMAIL]glcsong@163.com[/EMAIL][IMG]http://bbs.huizhou.cn/UploadFile/2007-9/20079821201636593.gif[/IMG] [URL=http://localhost/show_up.asp]远程网址链接[/URL]
转换为能够正常显示的HTML代码<img src="UploadFile/2007-9/20079119514934253.gif"><b>粗体</B><I>斜体</I><U>下划线</U><center>居中</center> <IMG src=" http://bbs.huizhou.cn/UploadFile/2007-9/20079821201636593.gif"> <a href=http://localhost/show_up.asp>远程网址链接</a>

问题解答：

你用什么语言来写，必须要正则表达式才好做，你如果要求用DELPHI、C++这些东西来做，要做死人的哦。

如果用ASP、PERL、PHP，基本上可以用它原来的语法，你改写成一个函数就行了。

function UBBCode(strContent)
if strAllowHTML <> 1 then
strContent = HTMLEncode(strContent)
end if
dim re
Set re=new RegExp
re.IgnoreCase =true
re.Global=True

if strIMGInPosts = "1" then
re.Pattern="(\[IMG\])(\S+?)(\[\/IMG\])"
strContent=re.Replace(strContent,"<IMG SRC=""$2"" border=0>")
end if

re.Pattern="\[DIR=*([0-9]*),*([0-9]*)\](.[^\[]*)\[\/DIR]"
strContent=re.Replace(strContent,"<object classid=clsid:166B1BCA-3F9C-11CF-8075-444553540000 codebase=http://download.macromedia.com/pub/shockwave/cabs/director/sw.cab#version=7,0,2,0 width=$1 height=$2><param name=src value=$3><embed src=$3 pluginspage=http://www.macromedia.com/shockwave/download/ width=$1 height=$2></embed></object>")
re.Pattern="\[QT=*([0-9]*),*([0-9]*)\](.[^\[]*)\[\/QT]"
strContent=re.Replace(strContent,"<embed src=$3 width=$1 height=$2 autoplay=true loop=false controller=true playeveryframe=false cache=false scale=TOFIT bgcolor=#000000 kioskmode=false targetcache=false pluginspage=http://www.apple.com/quicktime/>")
re.Pattern="\[MP=*([0-9]*),*([0-9]*)\](.[^\[]*)\[\/MP]"
strContent=re.Replace(strContent,"<object align=middle classid=CLSID:22d6f312-b0f6-11d0-94ab-0080c74c7e95 class=OBJECT id=MediaPlayer width=$1 height=$2 ><param name=ShowStatusBar value=-1><param name=Filename value=$3><embed type=application/x-oleobject codebase=http://activex.microsoft.com/activex/controls/mplayer/en/nsmp2inf.cab#Version=5,1,52,701 flename=mp src=$3 width=$1 height=$2></embed></object>")
re.Pattern="\[RM=*([0-9]*),*([0-9]*)\](.[^\[]*)\[\/RM]"
strContent=re.Replace(strContent,"<OBJECT classid=clsid:CFCDAA03-8BE4-11cf-B84B-0020AFBBCCFA class=OBJECT id=RAOCX width=$1 height=$2><PARAM NAME=SRC VALUE=$3><PARAM NAME=CONSOLE VALUE=Clip1><PARAM NAME=CONTROLS VALUE=imagewindow><PARAM NAME=AUTOSTART VALUE=true></OBJECT><br><OBJECT classid=CLSID:CFCDAA03-8BE4-11CF-B84B-0020AFBBCCFA height=32 id=video2 width=$1><PARAM NAME=SRC VALUE=$3><PARAM NAME=AUTOSTART VALUE=-1><PARAM NAME=CONTROLS VALUE=controlpanel><PARAM NAME=CONSOLE VALUE=Clip1></OBJECT>")

if strflash= "1" then
re.Pattern="(\[FLASH\])(.+?)(\[\/FLASH\])"
strContent= re.Replace(strContent,"<OBJECT codeBase=http://download.macromedia.com/pub/shockwave/cabs/flash/swflash.cab#version=4,0,2,0 classid=clsid:D27CDB6E-AE6D-11cf-96B8-444553540000 width=500 height=400><PARAM NAME=movie VALUE=""$2""><PARAM NAME=quality VALUE=high><embed src=""$2"" quality=high pluginspage='http://www.macromedia.com/shockwave/download/index.cgi?P1_Prod_Version=ShockwaveFlash' type='application/x-shockwave-flash' width=500 height=400>$2</embed></OBJECT>")
end if

re.Pattern="(\[ZIP\])(\S+?)(\[\/ZIP\])"
strContent=re.Replace(strContent,"<br><IMG SRC=pic/zip.gif border=0> <a href=""$2"">点击下载该文件</a>")
re.Pattern="(\[RAR\])(\S+?)(\[\/RAR\])"
strContent=re.Replace(strContent,"<br><IMG SRC=pic/rar.gif border=0> <a href=""$2"">点击下载该文件</a>")
re.Pattern="(\[UPLOAD=(\S+?)\])(.+?)(\[\/UPLOAD\])"
strContent= re.Replace(strContent,"<br><IMG SRC=""pic/$2.gif"" border=0><A HREF=""$3"" TARGET=_blank>新窗口打开图片</A><br><IMG SRC=""$3"" border=0>")

re.Pattern="(\[URL\])(http:\/\/\S+?)(\[\/URL\])"
strContent= re.Replace(strContent,"<A HREF=""$2"" TARGET=_blank>$2</A>")
re.Pattern="(\[URL\])(\S+?)(\[\/URL\])"
strContent= re.Replace(strContent,"<A HREF=""http://$2"" TARGET=_blank>$2</A>")

re.Pattern="(\[URL=(http:\/\/\S+?)\])(.+?)(\[\/URL\])"
strContent= re.Replace(strContent,"<A HREF=""$2"" TARGET=_blank>$3</A>")
re.Pattern="(\[URL=(\S+?)\])(.+?)(\[\/URL\])"
strContent= re.Replace(strContent,"<A HREF=""http://$2"" TARGET=_blank>$3</A>")

re.Pattern="(\[EMAIL\])(\S+\@\S+?)(\[\/EMAIL\])"
strContent= re.Replace(strContent,"<img align=absmiddle src=pic/email1.gif><A HREF=""mailto:$2"">$2</A>")
re.Pattern="(\[EMAIL=(\S+\@\S+?)\])(.+?)(\[\/EMAIL\])"
strContent= re.Replace(strContent,"<img align=absmiddle src=pic/email1.gif><A HREF=""mailto:$2"" TARGET=_blank>$3</A>")

re.Pattern = "^(http://[A-Za-z0-9\./=\?%\-&_~`@']+)"
strContent = re.Replace(strContent,"<img align=absmiddle src=pic/url.gif><a target=_blank href=$1>$1</a>")
re.Pattern = "(http://[A-Za-z0-9\./=\?%\-&_~`@']+)$"
strContent = re.Replace(strContent,"<img align=absmiddle src=pic/url.gif><a target=_blank href=$1>$1</a>")
re.Pattern = "[^>=""](http://[A-Za-z0-9\.\/=\?%\-&_~`@']+)"
strContent = re.Replace(strContent,"<img align=absmiddle src=pic/url.gif><a target=_blank href=$1>$1</a>")

if strIcons = "1" then
re.Pattern="(\[em(.+?)\])"
strContent=re.Replace(strContent,"<img src=pic/em$2.gif border=0 align=middle>")
end if

re.Pattern="(\[HTML\])(.+?)(\[\/HTML\])"
strContent=re.Replace(strContent,"<table width='100%' border='0' cellspacing='0' cellpadding='6' bgcolor='"&abgcolor&"'><td><b>以下内容为程序代码:</b><br>$2</td></table>")
re.Pattern="(\[code\])(.+?)(\[\/code\])"
strContent=re.Replace(strContent,"<table width='100%' border='0' cellspacing='0' cellpadding='6' bgcolor='"&abgcolor&"'><td><b>以下内容为程序代码:</b><br>$2</td></table>")

re.Pattern="(\[color=(.+?)\])(.+?)(\[\/color\])"
strContent=re.Replace(strContent,"<font color=$2>$3</font>")
re.Pattern="(\[face=(.+?)\])(.+?)(\[\/face\])"
strContent=re.Replace(strContent,"<font face=$2>$3</font>")
re.Pattern="(\[align=(.+?)\])(.+?)(\[\/align\])"
strContent=re.Replace(strContent,"<div align=$2>$3</div>")

re.Pattern="(\[QUOTE\])(.+?)(\[\/QUOTE\])"
strContent=re.Replace(strContent,"<BLOCKQUOTE><BLOCKQUOTE><table width='100%' border='0' cellspacing='0' cellpadding='6' bgcolor='"&abgcolor&"'><td>$2</td></table></BLOCKQUOTE></BLOCKQUOTE><br>")
re.Pattern="(\[fly\])(.+?)(\[\/fly\])"
strContent=re.Replace(strContent,"<marquee width=90% behavior=alternate scrollamount=3>$2</marquee>")
re.Pattern="(\[move\])(.+?)(\[\/move\])"
strContent=re.Replace(strContent,"<MARQUEE scrollamount=3>$2</marquee>")
re.Pattern="\[GLOW=*([0-9]*),*(#*[a-z0-9]*),*([0-9]*)\](.[^\[]*)\[\/GLOW]"
strContent=re.Replace(strContent,"<table width=$1 style=""filter:glow(color=$2, strength=$3)"">$4</table>")
re.Pattern="\[SHADOW=*([0-9]*),*(#*[a-z0-9]*),*([0-9]*)\](.[^\[]*)\[\/SHADOW]"
strContent=re.Replace(strContent,"<table width=$1 style=""filter:shadow(color=$2, strength=$3)"">$4</table>")

re.Pattern="(\[i\])(.+?)(\[\/i\])"
strContent=re.Replace(strContent,"<i>$2</i>")
re.Pattern="(\[u\])(.+?)(\[\/u\])"
strContent=re.Replace(strContent,"<u>$2</u>")
re.Pattern="(\[b\])(.+?)(\[\/b\])"
strContent=re.Replace(strContent,"<b>$2</b>")
re.Pattern="(\[fly\])(.+?)(\[\/fly\])"
strContent=re.Replace(strContent,"<marquee>$2</marquee>")

re.Pattern="(\[size=1\])(.+?)(\[\/size\])"
strContent=re.Replace(strContent,"<font size=1>$2</font>")
re.Pattern="(\[size=2\])(.+?)(\[\/size\])"
strContent=re.Replace(strContent,"<font size=2>$2</font>")
re.Pattern="(\[size=3\])(.+?)(\[\/size\])"
strContent=re.Replace(strContent,"<font size=3>$2</font>")
re.Pattern="(\[size=4\])(.+?)(\[\/size\])"
strContent=re.Replace(strContent,"<font size=4>$2</font>")

re.Pattern="(\[center\])(.+?)(\[\/center\])"
strContent=re.Replace(strContent,"<center>$2</center>")

strContent=ChkBadWords(strContent)

set re=Nothing
UBBCode=strContent
end function